home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 7
/
FM Towns Free Software Collection 7.iso
/
fb386
/
graf
/
a18.bas
< prev
next >
Wrap
BASIC Source File
|
1993-11-30
|
2KB
|
66 lines
1000 'A18.BAS***************************************************T.K.MOSAKU
1010 SCREEN@ 0:WINDOW (0,0)-(640,480):CLS
1020 POI(1)=0:POI(2)=6.5!:POI(3)=10:P=1
1030 A$="☆☆☆ シェルピンスキー曲線を大きさを変えて3度描き重ねています。 ☆☆☆"
1040 AA$="シェルピンスキー曲線"
1050 T1=TIME:S=1
1060 '
1070 LEV=2:C=2:GOSUB *MAIN
1080 AC=LEN(AA$):AD=(80-AC)\2:LOCATE 0,21:PRINT SPACE$(AD)+AA$
1090 WAIT 150
1100 LEV=3:C=4:GOSUB *MAIN
1110 CC=LEN(A$):D=(80-CC)\2:LOCATE 0,23:PRINT SPACE$(D)+A$
1120 WAIT 100
1130 LEV=4:C=5:GOSUB *MAIN
1140 T2=TIME:T=T2-T1:LOCATE 5,1:PRINT "描き上げる時間--";T;"秒 描いた曲線の数--";3;"本"
1150 LINE (221,131)-(427,336),PSET,5,B:LINE (219,129)-(429,338),PSET,5,B
1160 WAIT 200:GOTO 1640
1170 '
1180 *MAIN
1190 X1=60:Y1=60:XX=100:YY=0
1200 GOSUB *SETTEI
1210 FOR I=1 TO 4
1220 GOSUB *SEN
1230 LINE STEP(0,0)-STEP(X1,Y1),PSET,C'%C
1240 GOSUB *TURN90
1250 NEXT I
1260 RETURN
1270 '
1280 *SETTEI
1290 X2=370:Y2=280
1300 FOR I=LEV TO 1 STEP -1
1310 X1=X1/2:Y1=Y1/2:XX=XX/2:YY=YY/2
1320 X2=X2-X1:Y2=Y2-Y1:X2=X2-(XX-YY):Y2=Y2-(XX+YY)
1330 NEXT I
1340 Y2=Y2-Y1
1350 POINT (X2+POI(P),Y2+POI(P))
1360 P=P+1
1370 RETURN
1380 '
1390 *SEN
1400 IF LEV<=0 THEN RETURN
1410 LEV=LEV-1
1420 GOSUB *SEN
1430 LINE STEP(0,0)-STEP(X1,Y1),PSET,C'%C
1440 GOSUB *TURN90
1450 GOSUB *SEN
1460 LINE STEP(0,0)-STEP(XX,YY),PSET,C'%C
1470 LINE STEP(0,0)-STEP(XX,YY),PSET,C'%C
1480 GOSUB *SEN
1490 LINE STEP(0,0)-STEP(X1,Y1),PSET,C'%C
1500 GOSUB *TURN90
1510 GOSUB *SEN
1520 LEV=LEV+1
1530 RETURN
1540 '
1550 *TURN90
1560 TURN_X1=X1:X1=-Y1:Y1=TURN_X1
1570 TURN_XX=XX:XX=-YY:YY=TURN_XX
1580 RETURN
1590 '
1600 *TURN270
1610 TURN_X1=X1:X1=Y1:Y1=-TURN_X1
1620 TURN_XX=XX:XX=YY:YY=-TURN_XX
1630 RETURN
1640 '